¿Cómo puedo asociar los archivos URL con un navegador específico en Snow Leopard?

Que yo sepa, no hay manera de asociar .webloc archivos con una aplicación específica. Su mejor apuesta sería probablemente el uso de algunos de AppleScript.
He hecho un pequeño script que permite generar pequeño AppleScript aplicaciones que se abren en el navegador que usted seleccione a partir de la creación (OmniWeb, Safari o Chrome).

Puede descargar el script de aquí, o compilarlos desde el código de abajo.

set theURL to text returned of (display dialog "What URL would you like to bookmark?" with title "Enter URL" default answer "http://")
set theApp to (choose from list {"OmniWeb", "Safari", "Chrome"} with prompt "Which application would you like to associate with the bookmark?" with title "Select Application") as string
set theName to text returned of (display dialog "What would you like to name the bookmark?" with title "Enter Name" default answer "")
set theFolder to choose folder with prompt "Where would you like to save the bookmark?"

if theApp is "OmniWeb" then
    set theScript to "tell application \"OmniWeb\"
    activate
    try
        set theTab to make new tab at end of front browser with properties {address:\"" & theURL & "\"}
        set active tab of front browser to theTab
    on error
        make new browser with properties {address:\"" & theURL & "\"}
    end try
end tell"
else if theApp is "Safari" then
    set theScript to "tell application \"Safari\"
    activate
    try
        set theTab to make new tab at end of tabs of front window
        set the URL of theTab to \"" & theURL & "\"
    on error
        make new document
        set theTab to tab 1 of front window
        set the URL of theTab to \"" & theURL & "\"
    end try
    set current tab of front window to theTab
end tell"
else if theApp is "Chrome" then
    set theScript to "tell application \"Google Chrome\"
    activate
    if (count of windows) = 0 then
        make new window
        set URL of tab 0 of front window to \"" & theURL & "\"
    else
        set URL of (make new tab at end of tabs of front window) to \"" & theURL & "\"
    end if
end tell"
end if

tell application "AppleScript Editor"
    set theDoc to make new document with data theScript
    save theDoc as "application" in ((theFolder as string) & theName & ".app")
end tell

De la ejecución que le pedirá la URL, el navegador que usted desea que se abra, y la ubicación para guardar el 'marcador'.

Puedes poner esto en sus Aplicaciones o Scripts de la carpeta de fácil acceso y de invocar siempre que lo desee para guardar una dirección URL.

Necesita hacer un Script de Automator con estos elementos: (y guardar como una aplicación)

• -> RunShellScriptopen -a Firefox.app
• Pausa (2 segundos)
• -> RunShellScriptopen -a Firefox.app http://www.apple.com

Usted puede leer este artículo en la Macworld: http://www.macworld.com/article/142937/2009/09/snowfiles.html

Pero la carne de la corrección de la Solución de la sección es:

Control-clic sobre el archivo en cuestión, a continuación, mantenga presionada la tecla Opción y, a continuación, seleccione Abrir Siempre Con y seleccione la aplicación deseada de la (enorme) de la lista de alternativas. Tendrás que hacer esto cada vez que cree un nuevo archivo; no hay manera de establecer la aplicación de creación como la apertura predeterminada de la aplicación.

Estoy, por desgracia, en Windows en el trabajo, así que no puedo confirmar esta revisión. Pero suena a que es el camino a seguir.

La solución que está buscando no es simple. Una idea que me vino a la mente, yo he publicado en: enlazar la aplicación en el archivo particular de los nombres(en lugar de sufijo). Yo no soy un profesional de desarrollador de Apple, ni estoy familiarizado con los detalles intrincados de la OS. Pero como casual programador, creo que sería posible solución.

El de arriba si quieres seguir usando .webloc de curso. Lo que yo haría, aunque es el siguiente:

1. Cambiar la extensión de los particulares marcador archivos que desea abrir con una aplicación en particular a .url.
2. La asociación de estos con el navegador.