Cambio de la 'Nueva carpeta' nombre predeterminado

Con la ayuda de AppleScript puede lograr esto.

Abrir el Editor AppleScript, crear un nuevo documento y pega el siguiente robado líneas:

tell application "Finder"
    try
        if exists Finder window 1 then
            set thisPath to (the target of the front window) as alias
        else
            set thisPath to (path to desktop)
        end if
    on error
        return
    end try
end tell
set x to my the_perfect_datestring()
if x is not "-ERROR" then
    set fullPath to thisPath & x as text
    tell application "Finder"
        try
            --activate
            if not (exists fullPath) then
                set y to make new folder at thisPath with properties {name:x}
            end if
            activate
            open y
        end try
    end tell
end if
on the_perfect_datestring()
    try
        set cd to (the current date)
        set the_year to year of (cd) as number
        set the_month to month of (cd) as number
        set the_day to day of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        return ((the_year & the_month & the_day) as string)
    on error
        return "-ERROR"
    end try
end the_perfect_datestring

Guarde el archivo como AppleScript de la aplicación (por ejemplo, DateFolder.app) en algún lugar (e.g ~/Aplicaciones).

Abrir una carpeta y colocar el DateFolder.aplicación en la barra de herramientas:

Para crear una carpeta en una carpeta abierta simplemente pulse el icono de la aplicación en la barra de herramientas. La nueva carpeta se abrirá automáticamente. Quite la línea 22 en la secuencia de comandos (open y) si no desea que la nueva carpeta que se abrirá. Si usted agregar la aplicación a la base y abrirlo, se creará una nueva carpeta en la parte delantera de la carpeta o en el escritorio (si no hay ninguna carpeta abierta).

Sólo probado en Mac OS X 10.7.5. El león!

Para agregar un guión y el tiempo actual agregue las siguientes líneas (en sustitución de la línea de 32-34 en el script de arriba):

        set the_hour to hours of (cd) as number
        set the_minute to minutes of (cd) as number
        set the_second to seconds of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        if the_hour < 10 then set the_hour to "0" & the_hour
        if the_minute < 10 then set the_minute to "0" & the_minute
        if the_second < 10 then set the_second to "0" & the_second
        return ((the_year & the_month & the_day & "-" & the_hour & the_minute & the_second) as string)