Usando el método incorporado

Según la Base de Conocimientos de Apple, Numbers admite referencias absolutas:

Puedes establecer referencias de fila y columna en una fórmula como absolutas para poder usar la misma fórmula en otras partes de tu hoja de cálculo sin que las referencias de celdas cambien, como ocurriría de otra manera.

Para cambiar tu fórmula original y utilizar referencias absolutas, sigue estos pasos:

1. Doble clic en la celda original para entrar en modo de edición.
2. Para cada referencia, haz clic en el triángulo; luego marca ambas casillas Preservar fila y Preservar columna.

O, como alternativa al paso 2, puedes editar manualmente la referencia para que diga por ejemplo $A$1 en lugar de A1.

Las desventajas obvias de este método son:

• Básicamente, este método bloquea tu fórmula en un modo que dificulta reutilizar la misma fórmula en otros lugares donde realmente quieres referencias flexibles.

• Si deseas copiar muchas fórmulas originales diferentes, necesitas repetir el método una y otra vez.

Usar un AppleScript para Copiar Fórmulas

Un enfoque más reutilizable sería un simple AppleScript que replica el comando Copiar pero solo copia las fórmulas básicas:

on join(cells, delimiter)
  set previousDelimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to delimiter
  set resultString to (cells as text)
  set AppleScript's text item delimiters to previousDelimiters
  return resultString
end join

on getSelectedFormulas()
  set tab to character id 9
  set lf to character id 10

  tell application "Numbers"
    tell document 1's sheet 1's table 1
      tell selection range
        set {min, max} to {column 1's address, column -1's address}
        set formulaRows to {}
        repeat with aRow in rows
          set formulaCells to {}
          repeat with aCell in aRow's cells min thru max
            set formulaCells to formulaCells & (aCell's formula)
          end repeat
          set formulaRows to formulaRows & ¬
            my join(formulaCells, tab)
        end repeat
        return my join(formulaRows, lf)
      end tell
    end tell
  end tell
end getSelectedFormulas

on run()
  tell application "Numbers"
    set the clipboard to my getSelectedFormulas()
  end tell
end run

(Nota: Soy el autor del script; está bajo la licencia de código abierto ISC.)

Esto también elimina la necesidad de modificar las fórmulas originales.

Vincular el script a un atajo de teclado

Para vincular este script a un atajo de teclado en Numbers, abre Automator.app para crear un flujo de trabajo de Automator. Elige la opción Servicio recibe ninguna entrada en Numbers, crea un paso Ejecutar AppleScript y pega el código de AppleScript allí.

Guarda el flujo de trabajo con el nombre Copiar Fórmulas, luego abre Preferencias del Sistema y haz clic en Teclado, luego en Atajos de Teclado » Servicios » Numbers » Copiar Fórmulas. Configura un atajo de teclado; te recomendaría C porque probablemente lo vayas a usar a menudo con su contraparte, Pegar y Coincidir Estilo, que ya tiene el atajo V.