AppleScript para encontrar una ficha con su nombre en Google Chrome

No estar seguro de que el alcance total de lo que usted está tratando de lograr, el código puede ser más entonces usted necesita. Sin embargo, sí permite buscar el Nombre de la Pestaña y, a continuación, establece la Ficha que contiene la cadena de búsqueda como el active tab.

El código siguiente es un sistema de reparación de el código presentado en Encontrar Safari Pestañas con AppleScript. Habría sido agradable haber sido capaz de cambiar tell application "Safari" a tell application "Google Chrome" y el guión trabajado, pero debido a las diferencias en las propiedades de una Ficha entre las dos Aplicaciones, esta es la razón por la que no iba a funcionar.

Lo que este script :

• Muestra un cuadro de diálogo en el que puede escribir lo que se va a buscar en los Nombres de las Pestañas.
• Si la cadena de búsqueda coincide sólo en una Ficha, luego de que la Ficha se establece en la active tab index, lo que significa que la Ficha es ahora la pestaña actual. Si hay más de una ventana, la ventana que contiene la Ficha se llevó a la parte delantera de todos los otros servicios de Google Chrome de windows.
• Si la cadena de búsqueda hace varios partidos, a continuación, una lista de diálogo que se presenta a elegir, luego de que la Ficha se establece en la active tab index, lo que significa que la Ficha es ahora la pestaña actual. Si hay más de una ventana, la ventana que contiene la Ficha se llevó a la parte delantera de todos los otros servicios de Google Chrome de windows.
• Si la cadena de búsqueda no es correspondido, un cuadro de diálogo que indica "No se encontró ninguna coincidencia!" en la pantalla.

set searchString to text returned of (display dialog "Enter a string to search for:" default answer "" with title "Find Google Chrome Tab")

tell application "Google Chrome"
    set win_List to every window
    set win_MatchList to {}
    set tab_MatchList to {}
    set tab_NameMatchList to {}
    repeat with win in win_List
        set tab_list to every tab of win
        repeat with t in tab_list
            if searchString is in (title of t as string) then
                set end of win_MatchList to win
                set end of tab_MatchList to t
                set end of tab_NameMatchList to (id of win as string) & ".  " & (title of t as string)
            end if
        end repeat
    end repeat
    if (count of tab_MatchList) is equal to 1 then
        set w to item 1 of win_MatchList
        set index of w to 1
        my setActiveTabIndex(t, searchString)
    else if (count of tab_MatchList) is equal to 0 then
        display dialog "No match was found!" buttons {"OK"} default button 1
    else
        set which_Tab to choose from list of tab_NameMatchList with prompt "The following Tabs matched, please select one:"
        if which_Tab is not equal to false then
            set oldDelims to (get AppleScript's text item delimiters)
            set AppleScript's text item delimiters to "."
            set tmp to text items of (which_Tab as string)
            set w to (item 1 of tmp) as integer
            set AppleScript's text item delimiters to oldDelims
            set index of window id w to 1
            my setActiveTabIndex(t, searchString)
        end if
    end if
end tell

on setActiveTabIndex(t, searchString)
    tell application "Google Chrome"
        set i to 0
        repeat with t in tabs of front window
            set i to i + 1
            if title of t contains searchString then
                set active tab index of front window to i
                return
            end if
        end repeat
    end tell
end setActiveTabIndex