He intentado numerosas veces para reproducir el problema, sin embargo no podía. Así que esta solución fue probado por la introducción manual de una dirección URL estándar dos veces, a través de copiar y pegar, e ir de allí. También he usado la mala dirección URL que has mostrado en tu pregunta.
En Safari, básicamente, se trata de construir una dirección URL válida a partir de la doble dirección URL usando AppleScript que se ejecute como un Automator Servicio al presionar ⌘B y establece el documento actual (ventana o pestaña) a la URL correcta.
Crear un Automator Servicio con la configuración como se muestra en la imagen a continuación y guárdelo como:
Corregir la Mala URL
A continuación, en Preferencias del Sistema > Teclado > accesos directos > Servicios, desplácese hacia abajo a lo General, seleccione
Corregir la Mala dirección URL, haga clic en Agregar acceso directo y tipo: ⌘B
![Fix Bad URL Automator Service]()
AppleScript código para el Automator Servicio:
on badURL()
try
-- # Put the bad URL on the Clipboard.
tell application "Safari"
activate
delay 0.5
tell application "System Events"
key code 37 using {command down} # ⌘L
delay 0.5
key code 8 using {command down} # ⌘C
delay 0.5
end tell
end tell
-- # Retrieve the bad URL from the Clipboard.
set theBadURL to get (the clipboard)
-- # Trim the first eight characters off of 'theBadURL'.
-- # This is done because the bad URL can have an occurrence of both 'http' and 'https' in the string in either
-- # order and by trimming off, it lessens the amount of logic necessary to build a good URL from the bad URL.
-- # The good URL, after all, is going to be built from what's after the second occurrence of either one.
-- # Test first for 'https' then 'http', as that makes more sense logically to do so.
set theBadURL to do shell script "awk 'BEGIN { print substr(\"" & theBadURL & "\", 9) }'"
-- # Build the good URL from the bad URL.
set theGoodURL to do shell script "awk -F 'https.*//' '{print $2}'<<<" & quoted form of theBadURL
if theGoodURL is not equal to "" then
set theGoodURL to "https://" & theGoodURL
else
set theGoodURL to do shell script "awk -F 'http.*//' '{print $2}'<<<" & quoted form of theBadURL
if theGoodURL is not equal to "" then
set theGoodURL to "http://" & theGoodURL
end if
end if
return theGoodURL
on error eStr number eNum
display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with icon caution
return
end try
end badURL
on run
try
tell application "Safari"
activate
set thisTabsURL to (get URL of current tab of window 1)
-- # Check for bad URL and if found, build a good URL from it.
tell current application
if thisTabsURL contains "file:" then
set theGoodURL to my badURL()
tell application "Safari" to set the URL of the front document to theGoodURL
end if
end tell
end tell
on error eStr number eNum
display dialog eStr & " number " & eNum buttons {"OK"} default button 1 with icon caution
return
end try
end run
Tenga en cuenta que mientras he probado esto en OS X 10.8.5 y macOS 10.12 y funcionó bajo mis condiciones de prueba, sin embargo puede que no funcione correctamente cada vez que bajo cualquier condición y por lo tanto, por la try y on error declaraciones están siendo utilizadas en el código. Esperemos que este interceptar cualquier error(s) con salida correspondiente para luego mejorar el código para controlar cualquier error(s) que no se producen durante mis pruebas.
