¿Disminuir el brillo de la pantalla del MBP, utilizando AppleScript (y mientras se utiliza un monitor secundario)?

Este script fijará el valor del brillo de mi pantalla al 75% en mi MacBook Pro con OS Sierra si solo tengo disponible la pantalla retina en mis preferencias de pantalla

tell application "System Preferences"
    if it is running then
        quit
    end if
end tell
delay 0.2
activate application "System Preferences"
tell application "System Events"
    tell process "System Preferences"
        click button "Displays" of scroll area 1 of window "System Preferences"
        delay 1
        set value of value indicator 1 of slider 1 of group 2 of tab group 1 of window "Built-in Retina Display" to 0.75
    end tell
    delay 1
    quit application "System Preferences"
end tell

Este script establecerá el valor del brillo de mi pantalla al 75% en mi MacBook Pro ejecutando OS Sierra si tengo retina display disponible y tengo airplay activado y usando mi dispositivo airplay como segundo monitor en preferencias de pantalla.

tell application "System Preferences"
    if it is running then
        quit
    end if
end tell
delay 0.2
activate application "System Preferences"
tell application "System Events"
    tell process "System Preferences"
        click button "Displays" of scroll area 1 of window "System Preferences"
        delay 1
        click radio button "Display" of tab group 1 of window "Built-in Retina Display"
        set value of value indicator 1 of slider 1 of group 1 of tab group 1 of window "Built-in Retina Display" to 0.75
    end tell
    delay 1
    quit application "System Preferences"
end tell

Sin embargo, para estos dos scripts, mi pantalla retina integrada es mi monitor principal.

He aquí una versión revisada del script que fijará el brillo al 75% sin traer la aplicación de preferencias del sistema al frente. Creo que usted encontrará que esto es más eficiente.

tell application "System Preferences"
    reveal anchor "displaysDisplayTab" of pane "com.apple.preference.displays"
end tell
tell application "System Events" to tell process "System Preferences" to tell window "Built-in Retina Display"
    set value of value indicator 1 of slider 1 of group 2 of tab group 1 to 0.75
end tell
quit application "System Preferences"

La respuesta anterior de wch1zpink para Sierra no funciona con versiones posteriores de MacOS. En MacOS 10.15.5 veo 2 jerarquías de elementos diferentes aparecen en diferentes momentos, por lo que el manejo de ambos:

set brightness to 0.75
tell application "System Preferences"
    reveal anchor "displaysDisplayTab" of pane "com.apple.preference.displays"
end tell
tell application "System Events" to tell process "System Preferences" to tell window 1
    set tryUntil to (current date) + 2 -- 2 seconds
    repeat
        try
            tell group 1 to tell tab group 1
                set value of value indicator 1 of slider 1 to brightness
            end tell
            exit repeat
        on error errorMessage
            try
                tell tab group 1
                    set value of value indicator 1 of slider 1 to brightness
                end tell
                exit repeat
            end try
            if ((current date) > tryUntil) then
                error errorMessage
            end if
        end try 
    end repeat
end tell

En mis pruebas, esto se completa en entre 0,02 segundos y 0,7 segundos, dependiendo de si Preferencias del Sistema ya está abierto. El código de repetición provoca reintentos si la jerarquía de elementos aún no está lista.

Este AppleScript pondrá instantáneamente todas las pantallas en reposo.

do shell script "pmset displaysleepnow"

1. las pantallas se volverán a encender cuando muevas el ratón/toques el teclado
2. funciona tanto con pantallas internas como externas
3. no hay retraso en el oscurecimiento de la pantalla

Ese es el código que estoy usando en mi configuración multipantalla. Es una versión ligeramente modificada del código de Andrew D. Bond publicado anteriormente.

set brightness to 0.75
tell application "System Preferences"
    reveal anchor "displaysDisplayTab" of pane "com.apple.preference.displays"
end tell
tell application "System Events" to tell process "System Preferences" to tell window "Built-in Retina Display"
    set tryUntil to (current date) + 2 -- 2 seconds
    repeat
        try
            tell group 1 to tell tab group 1
                set value of value indicator 1 of slider 1 to brightness
            end tell
            exit repeat
        on error errorMessage
            try
                tell tab group 1
                    set value of value indicator 1 of slider 1 to brightness
                end tell
                exit repeat
            end try
            if ((current date) > tryUntil) then
                error errorMessage
            end if
        end try
    end repeat
end tell