Cuando abro un archivo DMG, ¿cómo puedo hacer que se abra delante de las ventanas?

Creé un script de Acción de Carpeta en Applescript que podría hacer exactamente lo que deseas. Cópialo y pégalo en un nuevo Applescript, y guárdalo como una Aplicación (¡sin un diálogo de inicio!) en "/Library/Scripts/Folder Action Scripts/". Luego puedes adjuntarlo a cualquier carpeta (probablemente tu carpeta ~/Downloads/) haciendo clic derecho en la carpeta y seleccionando "configurar acciones de carpeta" en el menú desplegable de servicios. Activa las Acciones de Carpeta y deja que el script observe la carpeta.

Básicamente, lo que hace el script es reaccionar ante los elementos que se arrastran a la carpeta a la que está adjunto y, si el elemento arrastrado es de Tipo:"Imagen", adjunta la imagen como un Volumen a través de la herramienta de línea de comandos "hdiutil".

Puedes configurar su comportamiento estableciendo las propiedades openWindow y makeFrontmost en el Script; también puedes hacerlo haciendo doble clic en el Script después de haberlo guardado como una aplicación; luego te preguntará en dos diálogos cuál debería ser su comportamiento estándar.

Espero que esto ayude,

Asmus

property openWindow : true
property makeFrontmost : true

on run

    display dialog "¿Quieres que el Finder tome el frente después de agregar nuevos elementos?" buttons {"No Activar", "Activar"} default button 2
    if the button returned of the result is "No Activar" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if

    display dialog "¿Abrir la carpeta después de agregar nuevos archivos?" buttons {"No Abrir", "Abrir"} default button 2
    if the button returned of the result is "No Abrir" then
        set openWindow to false
    else
        set openWindow to true
    end if

end run

on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

end adding folder items to

on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil attach " & itemPath & " | grep Volumes"

    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

        set currentDelim to text item delimiters
        set text item delimiters to tab

        set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

        set text item delimiters to currentDelim

        tell application "Finder" to open folder volumeMountpoint

    end if

end showImage

\====

segundo Applescript para determinar el tipo de archivo arrastrado en una carpeta

on adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Editado Necesita ser "Imagen de Disco" en lugar de "Imagen"