¿Cómo crear un servicio de Automator para cambiar la fuente del texto seleccionado?

Podrías asignar un acceso directo a un script así:

tell application "System Events" to tell (process 1 where frontmost is true)
    set {c1, c2} to value of attribute "AXSelectedTextRange" of text area 1 of scroll area 1 of window 1
end tell
tell application (path to frontmost application as text) to tell document 1
    tell characters c1 thru c2
        set font to "Menlo"
        set size to 18
    end tell
end tell

Funciona con TextEdit y WriteRoom, pero probablemente haya que modificarlo para otras aplicaciones.

Otra opción realmente horrible:

try
    set old to the clipboard as record
end try
do shell script "textutil -stdin -stdout -format html -convert rtf <<< '<span style=\"font: 18px Menlo\">a</span>' | pbcopy"
tell application "System Events"
    keystroke "v" using command down
    keystroke "c" using {option down, command down}
    keystroke "z" using command down
    keystroke "v" using {option down, command down}
end tell
delay 0.05
try
    set the clipboard to old
end try

Después de muchas investigaciones, el flujo de trabajo que sigue me funciona en TextEdit, Mail, Notes, Stickies. Donde no funciona es cuando la aplicación utiliza Estilos (Microsoft Word, Pages, Keynote), porque el estilo anula la fuente que introduces. La única forma que se me ocurre para anular el estilo es directamente script cada app para hacer un estilo personalizado.

Código ApplesScript:

on run {input, parameters}

    do shell script "pbpaste | textutil -stdin -stdout -convert rtf -font Arial -fontsize 12 | pbcopy"
    tell application "System Events" to keystroke "v" using command down

    return input
end run