Sin embargo, la solución de Automator de @Matt Love no convierte archivos PDF de varias páginas en TIFF individuales. Tendría que ejecutar dos flujos de trabajo de Automator por separado, uno para convertir los archivos PDF en imágenes y otro para cambiar el formato de los archivos de imagen. Como alternativa, puede considerar usando AppleScript con los Eventos de Imagen incorporados en Mac OS X .
A diferencia de un simple flujo de trabajo de Automator, el script dado a continuación (versión coloreada por la sintaxis aquí ) convierte las imágenes y archivos PDF a TIFF, hace la notificación de errores y no se rompe al no poder manejar algunos archivos. Antes de ejecutar el script, seleccione los archivos a procesar en Finder.
EDIT: Para los PDF de varias páginas, sólo se convierte la página 1.
# this script converts all PDFs and images selected in Finder
# to the TIFF format and appends .tif to the file name
set t to (time of (current date))
tell application "Finder" to set sel to selection
set errors to {}
tell application "Image Events"
repeat with img_file in sel
try
set img_file to img_file as text
set img to open img_file
save img as TIFF in (img_file & ".tif")
if (class of result) is not file then error "could not convert to TIFF"
close img
on error errMsg
set errors to errors & ((name of (info for (img_file as alias)) & ": " & errMsg & "\n") as text)
try
close img
end try
end try
end repeat
end tell
# error report
set errcount to length of errors
set msg to (((length of sel) - errcount) as text) & " files converted to TIFF in " & ¬
(((time of (current date)) - t) as text) & " seconds.\n\n"
if errors is not {} then
set msg to msg & errcount & " errors occurred: \n" & errors as text
end if
display dialog msg
