El curl comando en la do shell script comando es incorrecto. El -o opción espera un nombre de archivo o un nombre completo de la ruta nombre de archivo no sólo un camino como lo que la variable theFilePath contiene. Consulte la página man de curl, en un tipo de Terminal man curl y presione entrar y, a continuación, desplácese hacia abajo a -o, --output <file> , donde se establece: Write output to <file> instead of stdout.
Por lo que su do shell script comando debería verse así:
do shell script "curl " & quoted form of theFileURL & " -o " & quoted form of POSIX path of (theFilePath & "/" & theFile)
Si se incluye el / (barra) al final de el valor se establece para la theFilePath variable por ejemplo set theFilePath to "/Volumes/home/Downloads/" usted puede eliminar & "/" de la do shell script comando, que podría ser algo como:
do shell script "curl " & quoted form of theFileURL & " -o " & quoted form of POSIX path of (theFilePath & theFile)
Además, ya que usted ya ha establecido theFilePath usted puede utilizar esto en su tell application "Finder" declaración, e.g:
tell application "Finder" to open theFilePath as POSIX file
Si desea Buscador para activar la apertura del expediente, y dependiendo de cómo haya configurado theFilePath (con o sin /) utilice uno de los siguientes adecuadamente:
tell application "Finder" to open (theFilePath & "/" & theFile) as POSIX file
tell application "Finder" to open (theFilePath & theFile) as POSIX file
El AppleScript código que se muestra a continuación contiene las dos formas de la theFilePath variable y el do shell script comando junto con la versión dos de la tell application "Finder" declaración con un conjunto de comentarios con el líder de -- (doble guión).
set theFileURL to the clipboard
set {TID, AppleScript's text item delimiters} to {AppleScript's text item delimiters, "/"}
set theFile to text item -1 of theFileURL
set AppleScript's text item delimiters to TID
-- set theFilePath to "/Volumes/home/Downloads"
set theFilePath to "/Volumes/home/Downloads/"
try
-- do shell script "curl " & quoted form of theFileURL & " -o " & quoted form of POSIX path of (theFilePath & "/" & theFile)
do shell script "curl " & quoted form of theFileURL & " -o " & quoted form of POSIX path of (theFilePath & theFile)
display dialog "The download is finished!" buttons {"OK"} default button 1 with icon note giving up after 5
on error theError
display dialog "Error downloading the file:" & return & theFile & return & return & theError buttons {"OK"} default button 1 with icon 0 giving up after 5
end try
tell application "Finder" to open theFilePath as POSIX file
-- tell application "Finder" to open (theFilePath & "/" & theFile) as POSIX file
-- tell application "Finder" to open (theFilePath & theFile) as POSIX file
