¿Cómo filtrar tanto la dirección de origen como la de destino con una sola prueba?

Lamentablemente, las reglas son bastante limitadas, pero a veces se pueden utilizar buzones inteligentes para solucionar el problema.

Por ejemplo, si necesita una regla que realice una acción cuando se cumplan las condiciones (A O B) Y C, puede configurar un buzón inteligente llamado 'X' que contenga todos los correos electrónicos en los que (A O B) sea verdadero, y luego un segundo buzón inteligente llamado Y que contenga todos los correos electrónicos en los que (C sea verdadero Y el buzón sea X).

Si fuera necesario, podría configurar una regla que procese el contenido del buzón Y y ejecutarla manualmente (seleccione todos los mensajes del buzón Y y, a continuación, Mensaje->Aplicar reglas).

Esta pregunta volvió a aparecer en mi radar porque mi comentario fue votado, pero todavía no hay buenas respuestas, así que voy a ir más allá. ;) Es un ejercicio interesante.

Usted dice que "Tengo muchos filtros y algunos de ellos tienen varias direcciones de correo electrónico, por lo que tendría que pasar por todos ellos duplicando cada prueba De: y convirtiéndola en una prueba Cualquier destinatario: un quebradero de cabeza de mantenimiento además de todo el dolor inicial"

Este quebradero de cabeza de mantenimiento podría eliminarse mediante la magia de Applescript. El siguiente script toma los mensajes seleccionados en Apple Mail, recorre todos los campos de "remitente" para encontrar nuevos remitentes que no tengan ya una de estas reglas "de/cualquier destinatario", y si no crea una nueva regla con sus condiciones de regla "de/cualquier destinatario".

No estoy seguro de lo que está haciendo exactamente con las reglas de correo, pero supongo que está configurando carpetas para cada "conversación" de correo con cada dirección de correo electrónico. Yo sólo busco en el encabezado "de" para configurarlas, ya que un correo electrónico puede tener muchos destinatarios. Es aproximado y querrás modificarlo tú mismo. Por ejemplo, no hago ninguna comprobación de los nombres de los buzones, un nombre con una barra oblicua hará que se creen buzones adicionales.

¡Aquí está!

tell application "Mail"
    set _sel to get selected messages of first message viewer
    repeat with _msg in _sel
        set _senderEmail to extract address from sender of _msg
        set _ruleName to "Conversations with <" & _senderEmail & ">"
        set _mailRules to rules
        set foundIt to false
        repeat with _rule in _mailRules
            if ((extract address from name of _rule) is _senderEmail) then
                set foundIt to true
                exit repeat
            end if
        end repeat
        if not foundIt then
            set _senderName to "Conversations/" & (extract name from sender of _msg)
            if not (mailbox _senderName exists) then
                make new mailbox at end of mailboxes with properties {name:_senderName}
            end if
            set _destination to (mailbox _senderName)
            set newRule to make new rule at end of rules with properties {name:_ruleName, enabled:true, should move message:true, all conditions must be met:false}
            tell newRule
                make new rule condition at end of rule conditions with properties {rule type:from header, expression:_senderEmail, qualifier:does contain value}
                make new rule condition at end of rule conditions with properties {rule type:any recipient, expression:_senderEmail, qualifier:does contain value}
                set move message to _destination
            end tell
        end if
    end repeat
end tell