Forzar enlace URL para abrir con un navegador específico

Puedes usar el comando open para lograr esto usando un script de shell o un script de Apple. No es necesariamente la mejor manera, pero es la forma en que lo hago.

open http://apple.stackexchange.com -a Firefox.app

sería el comando básico para abrir esta página en Firefox. ¡Puedes envolver fácilmente esto en un agradable script de Apple, avísame si necesitas saber cómo hacerlo!

Puedes usar Choosy y establecer las reglas para la URL que has creado en Dock. No solo funciona para la URL en el Dock, sino que las reglas también se aplican a todos los enlaces que abres en Safari, Firefox o Chrome. Si necesitas que un determinado dominio o patrones de URL se abran en un navegador diferente, entonces Choosy es el que necesitas.

Utilizo el menú contextual en el archivo de URL para abrir el sitio en cualquier navegador:

• Haz clic derecho y selecciona la hoja de información
• Debajo de "Abrir con", elige Otro -> Mostrar todas las aplicaciones
• Selecciona el navegador web de tu elección

Ahora que hayas completado eso, muévelo al Dock y hará lo que querías.

Firefox (al menos mi versión, 27.0.1) parece no soportar archivos .url, desafortunadamente.

Entonces, lo que hice es crear un archivo .html que redirige a la URL correcta. Esto es todo lo que necesitas poner en el archivo, solo un documento de texto plano:

Reemplaza URL_GOES_HERE con la URL que desees, incluyendo http:// o https://.

Selecciona el archivo en Finder, Command ⌘+I para obtener información, y desplázate hacia abajo a Abrir Con, donde debería aparecer un menú desplegable que muestra Chrome. Cambia eso a Firefox. Encima de eso debería decir Nombre y Extensión; si tiene algo como .html.txt puedes cambiarlo a .html.

Aquí hay un Applescript que puedes guardar como una aplicación y acceder desde tu dock como cualquier otra aplicación normal.

Lo que hace

Te permite cambiar dinámicamente la URL a abrir si es necesario.

Esto significa que no tienes que codificar la URL en la aplicación.

Una vez que se establece una URL, solo necesitas hacer clic en la aplicación en cualquier momento en el Dock para abrirla en FireFox. O abrir la aplicación como de costumbre desde Finder.

Puedes cambiar la URL fácilmente en cualquier momento siguiendo el paso 1 a continuación.

Paso 1, Establecer la URL de la Aplicación:

Copia una URL al portapapeles y haz clic en la aplicación en el dock.

Comprobará si el portapapeles comienza con "http:"; si es así, significará que deseas establecer la URL para que la aplicación se abra en Firefox.

Se abrirá un cuadro de diálogo para confirmar esto y para que puedas hacer cualquier ajuste a la URL.

Luego establecerá la URL almacenada y limpiará el portapapeles.

Paso 2, Abrir la URL una vez que se haya establecido una URL:

Ahora, cada vez que hagas clic en la aplicación en el Dock, se abrirá la URL en Firefox.

Para cambiar la URL repite el paso 1.

El Applescript

(* URL almacenada *)
property theUrl : ""

on run

    (* comprobar si el portapapeles tiene una URL http *)
    set fromClip to the clipboard as string

    if fromClip starts with "http:" or fromClip starts with "https:" then
        (* El portapapeles tiene una URL http, por lo que esto significa que queremos actualizar la URL de la aplicación para abrirla en firefox *)

        (* Confirmar que es lo que queremos hacer y podemos hacer ajustes a la URL*)
        display dialog "Establecer nueva URL como " default answer fromClip buttons {"Cancelar", "Aceptar"} default button 1

        copy the result as list to {button_pressed, text_returned}
        if button_pressed is "Aceptar" then
            (* Establecer la URL en la propiedad almacenada *)
            set theUrl to text_returned

            (* Limpiar el portapapeles *)
            set the clipboard to ""
        end if

    else
        (* comprobar si el portapapeles NO comenzó con URL http *)
        if theUrl is not "" then
            (* Esto significa que queremos abrir la URL actual en firefox *)
            do shell script "open " & quoted form of theUrl & " -b org.mozilla.firefox"
        end if

    end if

end run

Nota:

Esto está escrito en OS X 10.9

Donde parece que la lista {text_returned, button_pressed} se invierte a {button_pressed, text_returned}

ACTUALIZACIÓN Segunda idea.

Para posiblemente satisfacer a alguien que no quiera usar el portapapeles y prefiera seguir usando un archivo (webloc)

Este Applescript, cuando se guarda como una aplicación en el Dock.

Cuando se ejecuta por primera vez, pedirá una carpeta donde se almacena el único archivo webloc.

La carpeta solo debería tener un archivo en su interior en todo momento.

Cuando se ejecuta en cualquier momento después, abrirá el archivo o cualquier otro que coloques en la carpeta.

Si no puede encontrar un archivo en la carpeta o la carpeta en sí misma cuando ejecutas la aplicación para abrir la URL, te advertirá y te ofrecerá la opción de restablecer la carpeta.

property theUrl : ""

on run

    if theUrl is not "" then
        try
            tell application "System Events" to set chosenFile to POSIX path of (file 1 of theUrl) whose visible is true

            do shell script "open " & quoted form of chosenFile & " -b org.mozilla.firefox"
        on error errm

            display dialog "ERROR: La carpeta de la URL puede estar vacía o no existir" with icon 0 buttons {"Restablecer Carpeta", "Aceptar"} default button 1 giving up after 5
            copy the result as list to {button_pressed, text_returned}
            if button_pressed is "Restablecer Carpeta" then
                set theUrl to (choose folder)
            end if
        end try
    else

        set theUrl to (choose folder)
    end if

end run