Crear un nuevo archivo (.txt) en el Finder - Atajo de teclado

He creado un AppleScript muy similar al de @YoshiBotX, pero con algunas mejoras.

La idea es crear un flujo de trabajo de Automator y asignarle un atajo usando los siguientes pasos:

• Abrir Automator y crear un Servicio ;
• Ponga la entrada en no hay entrada y la aplicación a Finder.app ;
• Arrastrar y soltar el Ejecute AppleScript elemento de flujo de trabajo en el espacio gris;
• Ponga el contenido de este AppleScript en el cuadro de texto;
• Guardar el flujo de trabajo con un nombre razonable (como Nuevo archivo );
• Ve a Configuración -> Teclado -> Atajos -> Servicios y asignarle un atajo.

Ahora, vamos a mostrar el AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Por comodidad, estoy poniendo este AppleScript en este GitHub Gist .

También podrías asignar un atajo a un script como esto:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

El lugar de inserción es o bien el objetivo de la ventana del Finder o el escritorio.

Puedes crear un Servicio de Automóviles tú mismo - es bastante simple de hacer. Luego puedes asignarle un atajo de teclado para no tener que activar el servicio a través del menú de servicios (lo cual puedes hacer de todas formas).

Abre Automator y selecciona Servicio como el tipo de documento nuevo.

Configura el servicio para que no reciba ninguna entrada en Finder.app y añade la acción Nuevo Documento de Edición de Texto al flujo de trabajo.

Guarde el servicio, luego abra Preferencias del Sistema → Teclado → Atajos → Servicios donde encontrará el servicio listado bajo General con el nombre que dio para el servicio cuando lo guardó.

Añade un atajo de teclado al servicio seleccionando el servicio y haciendo clic en "añadir atajo".

Aquí podría tener algunos problemas si el atajo ya se utiliza. Así que sé creativo para hacer uno que te funcione.

terminal abierto y tipo

touch filename

o

> filename