Acceso directo para expulsar todos los discos duros externos pero no MobileBackups

Puedes hacer lo siguiente en su lugar:

tell application "Finder"
  eject (every disk whose ejectable is true)
end tell

Si tiene montados discos con particiones, mantenga pulsada la tecla "Opción", ejecute su script, y suelte la tecla cuando termine.

He modificado ligeramente esto para hacer las exclusiones como un conjunto.

set exceptionsList to {"MobileBackups", "startup disk", "home", "net"}
tell application "Finder"
    set diskList to the disks
    repeat with mountedDisk in diskList
        if name of mountedDisk is not in exceptionsList then
            eject mountedDisk
        end if
    end repeat
end tell

Juntando las soluciones de Neil Ticktin y Dickster:

tell application "Finder"
    set diskList to the disks whose ejectable is true
    repeat with mountedDisk in diskList
        set mountedDiskName to the name of mountedDisk

        set skip to my skipDisk(mountedDiskName)
        if skip is false then
            eject mountedDisk
            log "ejected " & mountedDiskName
        else
            log skip
        end if

    end repeat
end tell

-- skipDisk is either `false` or a string explaining what was skipped and why
on skipDisk(diskName)
    set exceptionsList to {"TimeMachine", ".backup"}

    if diskName is in exceptionsList then
        return "skipped: \"" & diskName & "\" is in `exceptionsList`"
    end if

    repeat with exceptionDiskName in exceptionsList
        if diskName contains exceptionDiskName then
            return "skipped: \"" & diskName & "\" contains \"" & exceptionDiskName & "\""
        end if
    end repeat

    return false
end skipDisk