¿Puedo hacer que el Finder etiquete una carpeta si contiene un archivo o carpeta con un nombre específico?

Vi esta pregunta y me di cuenta de que la respuesta también me sería útil. Aquí está el Applescript que se me ocurrió. Cópialo en el Editor de Applescript, y ajusta las dos variables theSearchPath (primera línea) y el número de índice al final de la set label index línea y debería ser bueno para ir.

Estoy buscando ~/projects y colorear los resultados en verde en este caso.

set theSearchPath to "/Users/Me/projects"
set theResults to do shell script "find " & quoted form of theSearchPath & " -name .git"

repeat with i from 1 to (count paragraphs of theResults)
  set theResult to paragraph i of theResults
  set theParentPath to text 1 through ((length of theResult) - 5) of theResult
  set theParentAlias to POSIX file (theParentPath) as alias
  tell application "Finder"
    set label index of theParentAlias to 6
    -- Set the last value of the above line to correspond with the color you want.
    -- 0 is no color
    -- 1 is orange
    -- 2 is red
    -- 3 is yellow
    -- 4 is blue
    -- 5 is purple
    -- 6 is green
    -- 7 is gray
  end tell
end repeat

Nota: No se ha escrito para manejar con elegancia los errores escupidos por el find comando. Siempre que busques en directorios en los que tengas permisos, esto no debería ser un problema.

El script de Vickash no me funcionaba así que lo actualicé, y lo revisé ligeramente para poder encontrar cualquier extensión de archivo especificando la extensión en la variable theFileExtension (en mi caso, archivos .flac.) Funciona en Sierra.

set theSearchPath to "/Users/Me/projects"
set theFileExtension to ".flac"
set theResults to do shell script "find " & quoted form of theSearchPath & " -name *"&theFileExtension

repeat with i from 1 to (count paragraphs of theResults)
    set theResult to paragraph i of theResults
    set thePath to text 1 through ((length of theResult)) of theResult
    tell application "Finder"
        set theParentAlias to container of (POSIX file (thePath) as alias)
        set label index of theParentAlias to 1
        -- Set the last value of the above line to correspond with the color you want.
        -- 0 is no color
        -- 1 is orange
        -- 2 is red
        -- 3 is yellow
        -- 4 is blue
        -- 5 is purple
        -- 6 is green
        -- 7 is gray
    end tell
end repeat