Es allí una manera de no requerir una contraseña para inicio de sesión cuando estoy en casa, pero todavía requieren de uno en todas partes

He configurado mi sistema para hacer algo similar a lo que usted está tratando de hacer. Aunque yo personalmente nunca desactive mi contraseña de inicio de sesión (yo nunca recomiendo hacerlo por varias razones) me cambian algunos de mis configuración de seguridad de mi red doméstica local frente cuando estoy lejos de casa.

En primer lugar, usted querrá obtener e instalar ControlPlane (que NO he probado con El Capitan). Este complemento te permitirá cambiar un montón de ajustes en tu Mac basado en la ubicación de la información que se puede obtener de "las fuentes de evidencias". También tiene un montón de funciones integradas, es AppleScriptable, y de fuente abierta.

Una vez que haya ControlPlane instalado, usted necesitará crear un AppleScript que te permitirá activar o desactivar la contraseña de inicio de sesión basado en la información de ubicación.

El AppleScript que usted cree pueden ser diferentes, dependen de que Mac OS se ejecuta (en su caso El Capitan). Pero será similar a la secuencia de comandos que he creado en OS X 10.9.5 para hacer lo que quieres.

NOTA 1: Este scrip solo cambia la configuración de Seguridad Y Privacidad de la Página, NO tienen ninguna comprensión de la información de la ubicación. Usted probablemente desee crear una versión de este AppleScript para cada ubicación que ControlPlane identifica, y que se cambie la configuración en consecuencia.

NOTA 2: Esta secuencia de comandos requieren que el usuario introduzca su contraseña de administración dos veces al deshabilitar la contraseña de inicio de sesión y configuración del protector de pantalla. Yo no conozco una forma de evitar esto a menos que usted desea desplegable y hacer los shell scripts de ControlPlane, o añadir su contraseña en el archivo AppleScript y tienen que escriba por usted.

YO NO GARANTÍA O GARANTÍA ESTA SECUENCIA DE COMANDOS! UTILICE A SU PROPIO RIESGO YA QUE NO HE PROBADO CON EL CAPITAN.

-- !!! USE THIS SCRIPT AT YOUR OWN RISK !!!
-- !!! NO IMPLIED OR EXPLICIT GUARANTEES OR WARRANTIES ARE MADE !!!
-- USE OF THIS SCRIPT IS NOT GUARANTEED TO WORK ON ALL OS VERSIONS!

-- An AppleScript to Disable and Enable automatic login and sleep/screen saver password request.
-- This script may require the user to enter their administrative password twice when disabling.
-- This script ONLY toggles the settings found on the Security & Privacy page.

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preference.security"
    delay 1
    tell application "System Events"
        tell process "System Preferences"
            click menu item "Security & Privacy" of menu "View" of menu bar 1
            delay 0.5

            -- Check to see if the System Prefs are locked and editing is disabled.
            if title of checkbox 1 of window 1 is "Click the lock to make changes." then
                click checkbox 1 of window 1
                repeat until checkbox "Click the lock to prevent further changes." of window 1 exists
                    delay 0.1
                end repeat
            end if

            -- This should enable or disable "Disable automatic login"
            click checkbox "Disable automatic login" of tab group 1 of window 1
            repeat until not (exists sheet 1 of window 1)
                delay 0.1
            end repeat
            delay 0.5

            -- This should enable or disable "Require password after sleep or screen saver begins"
            click checkbox 1 of tab group 1 of window 1
            delay 0.25
            repeat until not (exists sheet 1 of window 1)
                click button "Turn Off Screen Lock" of sheet 1 of window 1
            end repeat
            delay 0.25
            -- BE CARFULE IF YOU CHANGE THIS AS IT COULD MODIFY YOUR KEYCHAIN!!!
            repeat until not (exists sheet 1 of window 1)
                click button "Keep Using Keychain" of sheet 1 of window 1
            end repeat

        end tell
    end tell
    tell application "System Preferences" to quit
end tell

Si utiliza este scrip como un AppleScript aplicación ASEGÚRESE de que su configuración de Accesibilidad son habilitado, de lo contrario no funcionará.