Guardar archivos adjuntos de Correo electrónico.aplicación basada en el tema

Primero, cree una regla que busca CUALQUIER de Manifiesto en todas las variaciones o DSR

Así:

A continuación, en guardar este script (asumiendo que usted está utilizando 10.8 Mountain Lion. ) En la carpeta ~/Library/Application Scripts/com.apple.correo/

    using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule

        set codeList to {"CV", "VS", "SAA", "TK", "DHV", "LH"}
        set subFolder to ""
        set theDate to do shell script "date +%Y_%m_%d_%H%M%S"
        --set ruleName to name of theRule





        -- The folder to save the attachments in (must already exist)
        tell application "Finder" to set attachmentsFolder to ((path to home folder as text) & "Dropbox:DSR") as text

        tell application "Mail"

            repeat with eachMessage in theMessages
                set theSubject to subject of eachMessage
                repeat with i from 1 to number of items in codeList
                    set this_item to item i of codeList
                    if theSubject contains this_item then

                        set subFolder to this_item

                    end if
                end repeat
                if (count of (eachMessage's mail attachments)) > 0 then


                    try

                        tell application "Finder"

                            if not (exists folder subFolder of folder attachmentsFolder) then
                                make new folder at attachmentsFolder with properties {name:subFolder}
                            end if
                        end tell
                        -- Save the attachment
                        repeat with theAttachment in eachMessage's mail attachments

                            set originalName to name of theAttachment
                            set savePath to attachmentsFolder & ":" & subFolder & ":" & originalName

                            tell application "Finder"

                                if (exists file originalName of folder subFolder of folder attachmentsFolder) then
                                    set savePath to attachmentsFolder & ":" & subFolder & ":" & theDate & "_" & originalName
                                end if
                            end tell
                            try
                                save theAttachment in file (savePath)



                            end try
                        end repeat


                    end try

                end if

            end repeat

        end tell
    end perform mail action with messages
end using terms from

Y el punto de Ejecutar Applescript.

Si usted está utilizando una anterior de Mac OS. Entonces usted debería ser capaz de colocar el script donde quiera.

Eso es todo.

Mis pruebas todos han trabajado. Pero ya es tarde aquí y debería estar en la cama. Así, hágamelo saber si alguno de los temas y voy a tratar y ordenar. :-)

La única cosa a tener en cuenta es que he añadido un sello de tiempo en lugar de un número para el mismo nombre de los archivos. Es más fiable.