Cambiar el ícono de la aplicación con un script

Usando la respuesta de @wch1zpink , pude llegar a una solución que utiliza el framework Foundation en lugar de la escritura de UI. Hay un inconveniente: funciona cuando se ejecuta en Automator pero no como una aplicación independiente. Para hacerlo así, necesita estar firmado ad hoc (Replicons.app es el nombre de mi aplicación.)

xattr -cr /Applications/Replicons.app && codesign --force --deep --sign - /Applications/Replicons.app

Luego, necesita ser concedido acceso completo al disco manualmente agregándolo a Configuración > Privacidad y seguridad > Acceso completo al disco

Al menos este es el caso en Sonoma 14.5

El script completo

(*
 Este applescript permite configurar de forma masiva iconos personalizados para aplicaciones (o carpetas)
 No puede establecer iconos para aplicaciones de sistema como Safari
   o aplicaciones que no posee como las instaladas desde la App Store
 Probado y funcionando en Sonoma 14.5

 USO: Cree un archivo de texto llamado replicons.cfg en su carpeta de Documentos
 siguiendo este formato

,
,
...

 El icono puede ser de tipo .icns o de un tipo de imagen como .png

 Ejemplo:

/Applications/Google Chrome.app,/Volumes/T7/icons/chrome dark.icns
/Applications/foobar2000.app,/Volumes/T7/Downloads/foobar2000.icns
/Applications/Spotify.app,/Users/me/Documents/icons/Spotify.png

 Para revertir un icono al predeterminado, deje el campo del icono vacío (nota la coma)

/Applications/Spotify.app,

 No deje líneas en blanco o espacios en blanco al principio/final.

 Discusión en Stackexchange
 https://apple.stackexchange.com/questions/473597/change-apps-icon-by-script

 ADVERTENCIA: para ejecutar como una aplicación independiente (en lugar de dentro de Automator), encontré que la aplicación
 tiene que ser firmada

 xattr -cr /Applications/nombredeapp.app && codesign --force --deep --sign - /Applications/nombredeapp.app

 y concedida acceso completo al disco manualmente agregándola a
 Configuración > Privacidad y seguridad > Acceso completo al disco
*)

use framework "Foundation"
use scripting additions

set configFile to (path to home folder as text) & "Documents:replicons.cfg"

-- Función para configurar el icono de una aplicación determinada
on setAppIcon(appPath, iconPath)
    try
        -- la magia sucede aquí
        if iconPath is "" then
            set image to missing value
        else
            set image to current application's NSImage's alloc()'s initByReferencingFile:iconPath
        end if
        set success to current application's NSWorkspace's sharedWorkspace's setIcon:image forFile:appPath options:0
        return success
    on error errStr number errorNumber
        display dialog errStr
        return false
    end try
end setAppIcon

-- Analizar una línea del archivo de configuración
on parseLine(aLine)
    set AppleScript's text item delimiters to ","
    set parsedList to text items of aLine
    set AppleScript's text item delimiters to ""
    return parsedList
end parseLine

-- Leer los pares de appIcon de un archivo de texto externo
set appIconPairs to {}

try
    set fileContents to read (configFile as alias)
    set fileLines to paragraphs of fileContents

    repeat with aLine in fileLines
        if aLine is not "" then
            set {appPath, iconPath} to my parseLine(aLine)
            copy {appPath, iconPath} to end of appIconPairs
        end if
    end repeat

on error errStr number errorNumber
    display dialog errStr
    return
end try

set successCount to 0

repeat with appIconPair in appIconPairs
    set {appPath, iconPath} to appIconPair
    if setAppIcon(appPath, iconPath) then
        set successCount to successCount + 1
    end if
end repeat

if successCount > 0 then
    -- Reiniciar el Dock para actualizar los iconos
    do shell script "killall Dock"
    display dialog "Se reemplazaron exitosamente " & (successCount as string) & " iconos."
else
    display dialog "No se realizó ningún cambio."
end if