Ocultar una extensión de archivo específica

No es exactamente una solución a través de Terminal, pero puedes lograr tu objetivo con un AppleScript.

Todo lo que necesitas hacer es crear una Acción Rápida utilizando Automator, y luego configurarla para ejecutar el siguiente script:

on run {input, parameters}

    tell application "Finder"
        repeat with eachItem in input
            # Buscar recursivamente en todas las subcarpetas.
            if kind of eachItem is "Folder" then
                set allFiles to (every file in entire contents of folder eachItem)
                repeat with eachFile in allFiles
                    my hideExtension(eachFile)
                end repeat
            else
                set eachFile to eachItem
                my hideExtension(eachFile)
            end if
        end repeat

        display dialog "Las extensiones de imagen han sido ocultadas exitosamente."
    end tell
    return
end run

on hideExtension(aFile)
    # Tal como PNG.
    # set fileExtension to name extension of aFile

    # Tal como imagen PNG.
    set fileKind to kind of aFile

    if fileKind ends with "image" then
        set extension hidden of aFile to true
    end if
end hideExtension

Aparentemente, mi script oculta la extensión para todas las imágenes. Puedes modificarlo para que se ajuste a tus necesidades.

Después de seguir todos los pasos, selecciona la carpeta que contiene los archivos de los cuales quieres ocultar las extensiones en Finder, haz clic derecho, en el menú de Acciones Rápidas, selecciona la Acción Rápida que acabas de crear. Las imágenes se pueden encontrar aquí.