¿Revelar enlace simbólico en Finder, NO el archivo al que resuelve?

En el ejemplo siguiente, el archivo 'man rsync269.pdf' era en realidad un enlace simbólico (creado con ln -s ). Tenga en cuenta que el select describe este archivo como un "archivo de alias" en lugar de como un "archivo de documento". El tercer elemento es ahora una carpeta.

Actualización: Añadido soporte para carpetas

tell application "Finder"
    set tPath to (insertion location)
    --> folder "random-storage" of folder "username" of folder "Users" of startup disk of application "Finder"
    set fileNameList to paragraphs of (the clipboard)
    --> {"man rsync269.pdf", "man unzip.pdf", "man pages"}

    set tOutput to {}
    repeat with ii from 1 to count of fileNameList
        try -- if file (includes alias files)
            set end of tOutput to file (item ii of fileNameList) of tPath
        on error -- if folder (technically, if not a file)
            set end of tOutput to folder (item ii of fileNameList) of tPath
        end try
        --> alias file man rsync269.pdf of folder "random-storage" of folder "username" of folder "Users" of startup disk
    end repeat

    select tOutput
    --> {alias file "man rsync269.pdf" of folder "random-storage" of folder "username" of folder "Users" of startup disk of application "Finder", document file "man unzip.pdf" of folder "random-storage" of folder "username" of folder "Users" of startup disk of application "Finder", folder "man pages" of folder "random-storage" of folder "username" of folder "Users" of startup disk of application "Finder"}
end tell

Alternativamente, creo que esto también funcionaría si se fuerza todo a texto y luego se precede cada referencia con archivo (es decir, componer una url de archivo).