Abrir una aplicación de fondo en primer plano

No, no es posible ejecutar una "aplicación de fondo" en primer plano.

No es que una aplicación que haya especificado "LSBackgroundOnly" simplemente tenga su ventana en segundo plano y "oculta a la vista". El programa realmente se ejecuta en un contexto en el que no puede abrir ninguna ventana.

Tendrás que poner "LSBackgroundOnly" en falso o eliminar la propiedad para poder ejecutar la app con una GUI mostrada. Ahora ya no es una "aplicación de fondo" - es una aplicación normal.

La única manera, creo, de hacer visible una aplicación cuyo "Info.plist" contiene "La aplicación es sólo de fondo" es Verdadero, es editar el archivo plist y establecer el valor de "La aplicación es sólo de fondo" a Falso o No o 0.

El siguiente código AppleScript le ayudará a hacer exactamente eso Muy rápidamente

activate
set plistFile to POSIX path of (choose file with prompt ¬
    "Select a .plist file to edit from within an app's \"Contents\" folder." of type ¬
    "com.apple.property-list" with invisibles and showing package contents)

set appName to do shell script "defaults read " & quoted form of plistFile & " CFBundleName"

try
    set currentStateOfBackgroundOnly to do shell script "defaults read " & ¬
        quoted form of plistFile & " LSBackgroundOnly"
on error errMsg number errNum
    set currentStateOfBackgroundOnly to "0"
end try

if currentStateOfBackgroundOnly = "0" then
    set appStatus to appName & " Is NOT currently running in \"Background Only\" mode."
else
    set appStatus to appName & " IS currently running in \"Background Only\" mode."
end if

activate
set theChoice to (choose from list {"Run In Background", "Don't Run In Background"} ¬
    with title "Run " & appName & ".app in the background only?" with prompt ¬
    appStatus & linefeed & linefeed & "Would you like to run " & appName & ¬
    ".app in the background only?" OK button name "OK" cancel button name "Cancel") as text

if theChoice = "Run In Background" then
    do shell script "defaults write " & quoted form of plistFile & " LSBackgroundOnly" & " -bool True"
else if theChoice = "Don't Run In Background" then
    do shell script "defaults write " & quoted form of plistFile & " LSBackgroundOnly" & " -bool False"
end if