Eventos del sistema script a veces funciona, a veces no

Question

Eventos del sistema script a veces funciona, a veces no

Preguntado el 23 de Junio, 2022: Cuando se hizo la pregunta
45 visitas: Cuantas visitas ha tenido la pregunta
1 Respuestas: Cuantas respuestas ha tenido la pregunta
Abierta: Estado actual de la pregunta

Esto es una parte de un script más grande que aislé y con el que tengo un problema:

tell application "Google Chrome" to activate
delay 2
tell application "System Events"
    click ¬
        pop up button "Multi Layout Manager" of ¬
        toolbar 1 of group 1 of window 1 of ¬
        application process "Chrome"
    delay 0.2
    repeat 3 times
        key code 48 -- # tab key
        delay 0.2
    end repeat
    key code 36 -- # enter key
end tell

Hace clic automáticamente en una extensión de Chrome (Multi Layout Manager) y selecciona una plantilla guardada.

A veces funciona a las mil maravillas y otras veces no. El error que obtengo es el siguiente:

error "System Events got an error: Can’t get pop up button \"Multi Layout Manager\" of toolbar 1 of group 1 of window 1 of application process \"Chrome\"." number -1728 from pop up button "Multi Layout Manager" of toolbar 1 of group 1 of window 1 of application process "Chrome"

No puedo entender lo que está mal aquí. Alguna ayuda sería genial. Gracias

Preguntado el 23 de Junio, 2022 por Jason Marsell

Answer 1

1 Respuestas

Answer 2

0voto

wch1zpink Puntos 11

No he podido probar este código siguiente porque no tengo pop up button "Multi Layout Manager" pero creo que esto debería conseguir lo que buscas.

tell application "Google Chrome" to activate
delay 2
tell application "System Events"
    set frontmost of application process "Google Chrome" to true
    repeat until application process "Google Chrome" is frontmost
        delay 0.1
    end repeat
    tell application process "Google Chrome"
        repeat until pop up button "Multi Layout Manager" of toolbar 1 of group 1 of window 1 exists
            delay 0.1
        end repeat
        click pop up button "Multi Layout Manager" of toolbar 1 of group 1 of window 1
        delay 0.2
        repeat 3 times
            key code 48 -- # tab key
            delay 0.2
        end repeat
        key code 36 -- # enter key
    end tell
end tell

Respondido el 24 de Junio, 2022 por wch1zpink (11 Puntos )

Eventos del sistema script a veces funciona, a veces no

Respuesta

Preguntas Destacadas

Etiquetas mas usadas

AppleAyuda.com

Powered by:

Eventos del sistema script a veces funciona, a veces no

Respuesta

Preguntas relacionadas

Preguntas Destacadas

Etiquetas mas usadas

En nuestra red

AppleAyuda.com

Powered by: